前回は、ラダーに必要なリレー、スイッチ等の部品の代わりに、命令語インタプリタを使うということで命令語の仕様を決定しました。
今回は、この命令語インタプリタをＶｉｓｕａｌ Ｂａｓｉｃで実際に作ってみます。

２．１ 命令語インタプリタの仕様
次の仕様の命令語インタプリタを作ることにします。

（１）命令語の仕様
Ｃｈａｐ．１の表１−１ 命令語インタプリタ命令セット（最小仕様）の通りです。
ただし、できるだけ処理を簡単にするため、オペコード（命令）とオペランド（Ｉ／Ｏ番号）は２行に分けて記述します。

例１

ＬＤ ０ ＡＮＤ １ ＯＵＴ ８０

また、プログラムを見やすくするため、コメント行を定義します。
行の先頭２文字が”／＊”という文字列になっているとき、命令語インタプリタはこの行をコメントとみなし無視します。

例２

／＊ この１行はコメント行です ＊／ ＬＤ ０ ＡＮＤ １ ＯＵＴ ８０

空白行も命令語インタプリタは無視します。

（２）Ｉ／Ｏ番号
１６進数で０からＦＦの２５６点のＩ／Ｏ番号とします。各Ｉ／Ｏは１ビットのデータを記憶できます。

（３）命令語プログラムファイル
命令語プログラムは、テキストファイルです。命令語インタプリタ自身に編集機能はありませんので、Ｗｉｎｄｏｗｓのメモ帳などのテキストエディタで作成することにします。

２．２ 機能
命令語インタプリタの機能についてみてみましょう。外観は図２．１の通りです。

図２．１ 命令語インタプリタの外観

ここで、２つの表示領域がありますが、左側には現在のＩ／Ｏデータを表示し、右側には命令語プログラムリストを表示します。
ボタンは、４つあり、各ボタンをクリックしたときの動作は表２．１の通りとなります。

表２．１ 各ボタンをクリックしたときの動作

ボタン名	機能
ファイル読み込み	命令語プログラムのファイル名を入力するウィンドが開きます。 ファイル名を入力すると、プログラムをインタプリタ内部に読み込みます。
スキャン実行	命令語プログラムを繰り返し実行します。
スキャン停止	命令語プログラムの実行を停止します。
データ入力	Ｉ／Ｏ番号と書込データを入力するウィンドウが開きます。 Ｉ／Ｏ番号と書込データを入力すると、指定したＩ／Ｏ番号のメモリにデータを書き込みます。

２．３ プログラムの作成
では、Ｖｉｓｕａｌ Ｂａｓｉｃでこのプログラムを作成してみましょう。

（１）コントロールの配置
まず、新規にプロジェクトを作成し、フォームに図２．２のようにコントロールを配置します。
表示領域には、リストボックスを使っています。また、スキャン実行のタイミングを得るためにタイマコントロールを使っています。

図２．２ コントロールの配置

（２）変数の定義
次に、このフォームにコードを記述します。
まず、表２．２のように変数を定義します。これらの変数は、フォーム内のどのプロシージャ・ファンクションからも見えるようにします。
具体的には、プログラムの先頭で、Ｄｉｍ Ｃｍｄ Ａｓ Ｓｔｒｉｎｇというようにして、各変数を定義してゆきます。

表２．２ 変数一覧

（３）各ボタンのイベント処理の記述
次に、各ボタンをクリックしたときの処理を記述します。
表２．３に処理内容を示します。この表を見てわかるように、スキャン実行、スキャン停止、データ入力では変数にデータをセットするだけで、実際の処理はタイマイベントでおこないます。

（４）タイマイベント処理の記述
命令語インタプリタの主要部分は、このタイマイベント処理です。
このタイマイベントの発生時間間隔は１００ｍｓで、これはフォームロード時にフォームロードイベントで値を設定します。
タイマイベントが発生するたびに、次の処理１〜処理３を行ないます。

処理１
変数Ｃｍｄをみて、もし文字列データがあれば、これをＩ／Ｏ番号と書き込みデータと見做し、指定されたＩ／Ｏ番号のメモリに指定されたデータを書き込みます。

処理２
変数ＲｕｎＦｌｇをみて、もしＴｒｕｅであれば、配列Ｐｒｇを順に読み出し、命令語を解析し、命令語の動作仕様に基づき実行します。

処理３
Ｉ／Ｏメモリの内容を表示領域に表示します。

以上が、命令語インタプリタの処理の概要です。コメントを除けば、プログラムは１００行以内でできるはずです。

２．４ プログラムリスト
参考のために、プログラムリストを掲載します。

---------- リストここから ----------
Option Explicit

'変数定義

Dim Prg(1023) As String '命令語プログラム
Dim LastPrg As Integer '命令語プログラム最終ポインタ＋１
Dim RunFlg As Boolean 'スキャン実行許可フラグ
Dim m(&HFF) As Boolean 'Ｉ／Ｏメモリ
Dim Reg As Integer '導通状態レジスタ
Dim Cmd As String 'Ｉ／Ｏメモリの変更指示（文字列）
Dim FileName As String '命令語プログラムファイル名

'名称：フォームロード処理
'機能：起動時の初期設定

Private Sub Form_Load() frmMain.Caption = "番外編 - 命令語インタプリタ V1.0"
lstMon.Font = "ＭＳ ゴシック"
lstPrg.Font = "ＭＳ ゴシック"
Timer1.Interval = 100 '１００ｍｓ毎にタイマイベント発生
End Sub
'名称：「ファイル読み込み」ボタン処理
'機能：命令語プログラムを読み込み、配列に格納する

Private Sub cmdFile_Click()
LastPrg = 0
Open InputBox("命令語ファイル名を入力してください。") For Input As #1
lstPrg.Clear
Do While Not EOF(1)
Line Input #1, Prg(LastPrg)
lstPrg.AddItem Prg(LastPrg)
LastPrg = LastPrg + 1
Loop
Close #1
End Sub

'名称：「スキャン実行」ボタン処理
'機能：スキャン実行許可フラグをＯＮする（実際のスキャン実行は、タイマ処理でおこなう）

Private Sub cmdScanRun_Click()
RunFlg = True 'スキャン実行許可フラグをＯＮ
End Sub

'名称：「スキャン停止」ボタン処理
'機能：スキャン実行許可フラグをＯＦＦする

Private Sub cmdScanStop_Click() RunFlg = False 'スキャン実行許可フラグをＯＦＦ
End Sub

'名称：「データ入力」ボタン処理
'機能：入力ボックスを開き、Ｉ／Ｏメモリの変更指示（文字列）を受け取る（実際の変更は、タイマ処理でおこなう）

Private Sub cmdInput_Click()
Cmd = InputBox("「アドレス２桁＋空白１文字＋データ１桁」の形式で、半角４文字で入力してください。（例 2E 1）", "データ入力", "")
End Sub

'名称：タイマ処理
'機能：Ｉ／Ｏメモリ変更、命令語プログラムを１スキャン実行、Ｉ／Ｏ表示をおこなう

Private Sub Timer1_Timer()
Dim i As Integer
Dim j As Integer
'指示されたＩ／Ｏメモリを変更する
If Cmd <> "" Then '変更指示があるとき
If Right(Cmd, 1) = "1" Then '１のとき
m(Val("&H" + Left(Cmd, 2))) = True 'ＯＮに変更
Else '１以外のとき
m(Val("&H" + Left(Cmd, 2))) = False 'ＯＦＦに変更
End If
End If
Cmd = ""
If RunFlg = True Then 'スキャン実行許可フラグがＴｒｕｅのとき
'命令語プログラムを１スキャン実行する
For i = 0 To LastPrg - 1
Select Case Prg(i)
Case "LD" 'ＬＤ命令のとき
i = i + 1
Reg = m(Val("&H" + Prg(i)))
Case "LDNOT" 'ＬＤＮＯＴ命令のとき
i = i + 1
Reg = Not (m(Val("&H" + Prg(i))))
Case "AND" 'ＡＮＤ命令のとき
i = i + 1
Reg = Reg And m(Val("&H" + Prg(i)))
Case "ANDNOT" 'ＡＮＤＮＯＴ命令のとき
i = i + 1
Reg = Reg And (Not (m(Val("&H" + Prg(i)))))
Case "OR" 'ＯＲ命令のとき
i = i + 1
Reg = Reg Or m(Val("&H" + Prg(i)))
Case "ORNOT" 'ＯＲＮＯＴ命令のとき
i = i + 1
Reg = Reg Or (Not (m(Val("&H" + Prg(i)))))
Case "OUT" 'ＯＵＴ命令のとき
i = i + 1
m(Val("&H" + Prg(i))) = Reg
Case "END" 'ＥＮＤ命令のとき
Exit For
Case Else '上記以外のとき
If Left(Prg(i), 2) <> "/*" Then End 'コメント以外のとき、終了
End Select
Next
End If
'Ｉ／Ｏメモリを画面に表示する
lstMon.Clear
For i = 0 To &HF8 Step 16
lstMon.AddItem Right("0" & Hex(i), 2) & "-" & Right("0" & Hex(i + &HF), 2) & " " _
& OnOff(m(i + 0)) & OnOff(m(i + 1)) & OnOff(m(i + 2)) & OnOff(m(i + 3)) & " " _
& OnOff(m(i + 4)) & OnOff(m(i + 5)) & OnOff(m(i + 6)) & OnOff(m(i + 7)) & " " _
& OnOff(m(i + 8)) & OnOff(m(i + 9)) & OnOff(m(i + 10)) & OnOff(m(i + 11)) & " " _
& OnOff(m(i + 12)) & OnOff(m(i + 13)) & OnOff(m(i + 14)) & OnOff(m(i + 15))
Next
End Sub

'名称：ｂｏｏｌｅａｎ−文字列変換
'機能：ｂｏｏｌｅａｎを０または１の文字列に変換する

Private Function OnOff(x As Boolean) As String
If x = True Then 'Ｔｒｕｅのとき
OnOff = "1" '１を返す
Else 'Ｆａｌｓｅのとき
OnOff = "0" '０を返す
End If
End Function ---------- リストここまで ----------

２．５ インタプリタを実行してみる
できあがった命令語インタプリタで次のプログラムを実行してみましょう。
このプログラムは、１スキャン毎にデータが反転します。アドレスＦ０が反転動作しているのが見えたらＯＫです。

/* 1ｽｷｬﾝ反転ｸﾛｯｸ(F0) */ LDNOT F0 OUT F0 END

次回はこの命令語インタプリタを使って、命令語プログラムを実行してみることにしましょう。